【Godot Engine】GDScriptメモ➁：基本的な演算子と処理構文(分岐/ループ処理)

データ型による分岐：typeof()と組み込み定数のTYPE_XXを使用します

match typeof(x):	#typeof()によって変数xのデータ型を取得
	TYPE_FLOAT:		#xがfloat型の場合
		print("float")
	TYPE_STRING:		#xがstring型の場合
		print("string")

複数の一致条件(OR)：「,」区切りで複数パターンのいずれかに一致した場合の判定が可能

match x:
	1, 2:
		print("xは１か2です")
	_ :
		print("xは1か2ではありません")

変数への代入：matchで変数への代入を行うことも可能です。(判定としては「_」と同様)

match x:
	1:
		print("xは1です。")
	var x_value:		#xが1ではない時、x_valueへxの値を代入
		print("xは1ではなく、", x_value,"です。")

配列の分岐：
　配列を判定する場合はサイズを含めた完全一致が基本で、そこに「_」や「..」 を加えて記述

match x:
	[]:
		print("空の配列です")
	[1, 2, 3]:
		print("[1,2,3]の配列です")
	[_, 10]:
		print("要素数が2つで、末尾が10の配列です")
	[10, 20, ..]:
		print("先頭から要素が[10],[20]の配列です")

辞書型の分岐：
　辞書型も配列とほぼ同様ですが、「Key/Value」毎に判定が可能です。(配列と同じ記法は割愛)

match x:
	{"A": 10, "B":20}:
		print("{A: 10, B:20} の辞書型です" )
	{"A": 10, "B"}:
		print("{A:10}と、キー値 B を持つ辞書型です")	#BのValue値は不問
	{"A", "B"}:
		print(":要素数が2で、キー値がA,B を持つ辞書型")	#各Value値は不問

条件式の組み合わせ(パターンガード)：
　whenを使うことで、変数への代入などと組み合わせた分岐条件の指定も可能です。

match x:
	[var a, var b] when a > b:
		print("aはbよりも大きい値です。： (%s, %s)" % [a, b])
	[var a, var b] when a < b:
		print("aはbよりも小さい値です。： (%s, %s)" % [a, b])
	[var a, var b]:
		print("aとbの値は一致しています。： (%s, %s)" % [a, b])

for文は用法が多いため、以下にいくつかの使用例をまとめておきます。

var data = [10,20,30]
for i in data:
	print(i)	# 10,20,30 と出力

var dict = {"a": 0, "b": 1, "c": 2}
for i in dict:
	print(i)	# a, b, c と出力
	print(dict[i]) # 0, 1, 2　と出力

for i in range(3):
	print(i) # 0, 1, 2 と出力

for i in 3:
	print(i) # 0, 1, 2 と出力(range(3)と同様)

for i in range(1, 3):
	print(i)	#1, 2 と出力

for i in range(2, 10, 2):
	print(i)	#2, 4, 6, 8 と出力

for c in "ABC":
	print(c)	#A, B, C と出力

for文のループ変数はループ内のローカル変数です。
そのため、ループ変数へ代入や変更を行っても元となったリストデータへは反映されません。
→リストデータを編集したい場合は、以下のような書き方をします

# 配列内の各要素を更新する
var data = [1,1,1]
for i in data.size():
	data[i] = 2	#ループ変数は元の配列の引数として使用

print(data)	#出力は [2,2,2]

# 二次元配列の末尾にデータを追加する
var array_list = [[1,1], [2,2]]
for array in array_list:
	array.append(3)		# 参照によって渡されているオブジェクトは編集可能

print(array_list)	#出力は [[11, 12, 3], [21, 22, 3]]